conversion to the cmake buildidng system

Signed-off-by: gregory guy <g-gregory@gmx.fr>

8 files changed, 217 insertions, 0 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644
index 0000000..bf31ff6
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,78 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( kbookreader )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### user requested modules
+
+option( BUILD_ALL "Build all" ON                             )
+option( BUILD_DOC "Build documentation" ${BUILD_ALL}         )
+option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H -UTQT_NO_ASCII_CAST )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+add_subdirectory( images )
+tde_conditional_add_subdirectory( BUILD_DOC doc         )
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po ) 
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )
diff --git a/ConfigureChecks.cmake b/ConfigureChecks.cmake
new file mode 100644
index 0000000..7733a2a
--- /dev/null
+++ b/ConfigureChecks.cmake
@@ -0,0 +1,45 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  if( NOT UNIX )
+    tde_message_fatal( "gcc visibility support was requested, but your system is not *NIX" )
+  endif( NOT UNIX )
+  set( __KDE_HAVE_GCC_VISIBILITY 1 )
+  set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+  set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+endif( WITH_GCC_VISIBILITY )
+
+
+##### gettext
+
+if( BUILD_TRANSLATIONS )
+  include( FindGettext )
+  if( GETTEXT_FOUND )
+    set( MSGFMT_EXECUTABLE ${GETTEXT_MSGFMT_EXECUTABLE} 
+      CACHE FILEPATH "path to msgfmt executable" )
+  endif( GETTEXT_FOUND )
+  
+  if( NOT MSGFMT_EXECUTABLE )
+    tde_message_fatal( "msgfmt is required but was not found on your system." )
+  endif( NOT MSGFMT_EXECUTABLE )
+endif( BUILD_TRANSLATIONS )
+
diff --git a/config.h.cmake b/config.h.cmake
new file mode 100644
index 0000000..61ede3a
--- /dev/null
+++ b/config.h.cmake
@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@
diff --git a/doc/CMakeLists.txt b/doc/CMakeLists.txt
new file mode 100644
index 0000000..6d0aa9f
--- /dev/null
+++ b/doc/CMakeLists.txt
@@ -0,0 +1 @@
+tde_auto_add_subdirectories( )
diff --git a/doc/en/CMakeLists.txt b/doc/en/CMakeLists.txt
new file mode 100644
index 0000000..98b15b2
--- /dev/null
+++ b/doc/en/CMakeLists.txt
@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION bookreader  )
diff --git a/images/CMakeLists.txt b/images/CMakeLists.txt
new file mode 100644
index 0000000..7ae3d0a
--- /dev/null
+++ b/images/CMakeLists.txt
@@ -0,0 +1,4 @@
+install(
+    FILES bg.png splash.png bookmark.png
+    DESTINATION ${DATA_INSTALL_DIR}/bookreader/themes/default
+)
diff --git a/po/CMakeLists.txt b/po/CMakeLists.txt
new file mode 100644
index 0000000..597c341
--- /dev/null
+++ b/po/CMakeLists.txt
@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+   tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )
+endif( )
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
new file mode 100644
index 0000000..5224cac
--- /dev/null
+++ b/src/CMakeLists.txt
@@ -0,0 +1,75 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### bookreader (executable)
+
+tde_add_executable( bookreader AUTOMOC
+
+  SOURCES
+        settingsdlg.ui
+        main.cpp
+        bookreader.cpp
+        bookreaderiface.skel
+        bookwidget.cpp
+        theme.cpp
+        settings.kcfgc
+        renderer.cpp
+        bookmark.cpp
+        bookmarksdlg.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+     tdeprint-shared
+
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+
+##### bookreader_client (executable)
+
+tde_add_executable( bookreader_client AUTOMOC
+
+  SOURCES
+        bookreader_client.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+
+##### icons
+
+tde_install_icons( )
+
+
+##### other data
+
+install(
+    FILES bookreaderui.rc
+    DESTINATION ${DATA_INSTALL_DIR}/bookreader
+)
+
+install(
+    FILES bookreader.desktop
+    DESTINATION ${APPS_INSTALL_DIR}/Office
+)
+
+install(
+    FILES bookreader.kcfg
+    DESTINATION ${KCFG_INSTALL_DIR}
+)