#MIN_CONFIG(3.2)
CXXFLAGS="$CXXFLAGS $KDE_DEFAULT_CXXFLAGS"

if test "$build_arts" = "yes"; then
    AC_DEFINE(USE_ARTS, 1, [If we use arts volume])
    LIB_ARTS="-lartskde"
    AC_SUBST(LIB_ARTS)
fi

KDE_INIT_DOXYGEN([The API Reference], [Version $VERSION])

# -----------------------------------------------------------------
#
# pkg config check
#
# -----------------------------------------------------------------

AC_ARG_VAR(PKGCONFIGFOUND, [Path to pkg-config])
AC_CHECK_PROG(PKGCONFIGFOUND, pkg-config,[yes])

#------------------------------------------------------------------
#
# Check for ffts
#
#------------------------------------------------------------------

LIB_FFTS=""

if test x$PKGCONFIGFOUND = xyes; then
    PKG_CHECK_MODULES(FFTS, ffts >= 0.7, have_ffts=yes,have_ffts=no)

    if test x$have_ffts = xyes; then
        AC_DEFINE(HAVE_FFTS, 1, [have FFTS transform library])
        LIB_FFTS=`pkg-config --libs ffts`
    fi
fi

AC_SUBST(LIB_FFTS)
AM_CONDITIONAL(with_included_ffts, [test x$included_ffts = xyes])

#------------------------------------------------------------------
#
# Check for heimdal kerberos
#
#------------------------------------------------------------------
PKG_CHECK_MODULES(KRB5, krb5, have_krb5=yes, have_krb5=no)
if test "x$have_krb5" = "xno"; then
  # Try to find krb5 without pkg-config file (required for older distros)
  AC_MSG_CHECKING(krb5)
  AC_FIND_FILE(krb5.h, [\
    /usr/local/include/heimdal /usr/local/include \
    /usr/include/heimdal /usr/include \
    ], krb5_includes)
  if test "x$krb5_includes" != "xNO"; then
    krb5_multiarch="`gcc -print-multiarch 2>/dev/null`"
    AC_FIND_FILE(libkrb5.so, [\
        /usr/local/lib/$krb5_multiarch/heimdal /usr/local/lib64/heimdal /usr/local/lib/heimdal \
        /usr/local/lib/$krb5_multiarch /usr/local/lib64 /usr/local/lib \
        /usr/lib/$krb5_multiarch/heimdal /usr/lib64/heimdal /usr/lib/heimdal \
        /usr/lib/$krb5_multiarch /usr/lib64 /usr/lib \
        ], krb5_libs)
    if test "x$krb5_libs" != "xNO"; then
      AC_MSG_RESULT([libraries $krb5_libs, headers $krb5_includes])
      CPPFLAGS="$CPPFLAGS -I$krb5_includes"
      CFLAGS="$CFLAGS -I$krb5_includes"
      LDFLAGS="$LDFLAGS -L$krb5_libs"
      AC_CHECK_HEADER(krb5.h, have_krb5=yes)
    fi
  fi
  if test "x$have_krb5" != "xno"; then
    KRB5_CFLAGS="-I$krb5_includes"
    KRB5_LIBS="-L$krb5_libs -lkrb5"
    AC_SUBST(KRB5_CFLAGS)
    AC_SUBST(KRB5_LIBS)
  else
    AC_MSG_RESULT(no)
  fi
fi
if test "x$have_krb5" = "xno"; then
  AC_MSG_ERROR([krb5 library is needed but not found on our system])
fi