summaryrefslogtreecommitdiffstats
path: root/kftpgrabber/configure.in.in
blob: 5fe7ac0d907026a9ac2795a2e26e8f04cbb32078 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
#MIN_CONFIG(3.2.0)

AM_INIT_AUTOMAKE(kftpgrabber, 0.8.0)

dnl Check for the 3.4 kde version (for tdednssd)
AC_DEFUN([CHECK_TDEDNSSD],
[
  AC_MSG_CHECKING(for TDEDNSSD support)
  AC_CACHE_VAL(ac_cv_tdednssd,
  [
    AC_LANG_SAVE
    AC_LANG_CPLUSPLUS

    save_CXXFLAGS="$CXXFLAGS"

    CXXFLAGS="$CXXFLAGS $all_includes"

    AC_TRY_LINK([
      #include <tdeversion.h>
    ],
    [
      #if ! KDE_IS_VERSION(3,4,0)
         KDE_choke me
      #endif
    ],
      ac_cv_tdednssd=yes,
      ac_cv_tdednssd=no
    )
    CXXFLAGS="$save_CXXFLAGS"
    AC_LANG_RESTORE
   ])

  if test "$ac_cv_tdednssd" = "yes"; then
    AC_MSG_RESULT(yes)
    LIB_TDEDNSSD="-ltdednssd"
  else
    AC_MSG_RESULT(no)
    LIB_TDEDNSSD=""
  fi

  AC_SUBST(LIB_TDEDNSSD)
])


dnl Check for the correct kde version
AC_DEFUN([CHECK_KDEVERSION],
[
  AC_MSG_CHECKING(for KDE >= 3.3)
  AC_CACHE_VAL(ac_cv_kde33,
  [
    AC_LANG_SAVE
    AC_LANG_CPLUSPLUS

    save_CXXFLAGS="$CXXFLAGS"

    CXXFLAGS="$CXXFLAGS $all_includes"

    AC_TRY_LINK([
      #include <tdeversion.h>
    ],
    [
      #if ! KDE_IS_VERSION(3,3,0)
         KDE_choke me
      #endif
    ],
      ac_cv_kde33=yes,
      ac_cv_kde33=no
    )
    CXXFLAGS="$save_CXXFLAGS"
    AC_LANG_RESTORE
   ])

  if test "$ac_cv_kde33" = "yes"; then
    AC_MSG_RESULT(yes)
  else
    AC_MSG_RESULT(no)
    
    echo ""
    echo " * You don't have KDE 3.3 or later installed on your system."
    echo " * KFTPGrabber requires at least KDE 3.3 or later."
    echo ""
    exit 1
  fi
])

dnl Stuff required for libssh
AC_CHECK_LIB([resolv],[gethostbyname])
AC_CHECK_LIB([nsl],[gethostbyname])

AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h \
sys/time.h termios.h unistd.h openssl/aes.h openssl/blowfish.h zlib.h \
sys/poll.h ])

AC_FUNC_MALLOC
AC_FUNC_MEMCMP
AC_FUNC_REALLOC
AC_FUNC_SELECT_ARGTYPES
AC_TYPE_SIGNAL
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([endpwent gethostbyaddr gethostbyname getpass memmove memset \
 select socket strchr strdup strerror strstr poll])

dnl Check for some stuff
KDE_CHECK_SSL
CHECK_KDEVERSION
CHECK_TDEDNSSD

AC_C_BIGENDIAN
AC_CHECK_KDEMAXPATHLEN