Live ebuilds: Add hldig (htdig fork) ebuild.

Lays groundwork for later KHelpCenter support.

Signed-off-by: Chris <xchrisx@uber.space>

www-misc/hldig/Manifest

@@ -0,0 +1 @@
+DIST v1.0.2.tar.gz 3913213 BLAKE2B def6fe7b05391f3956f1930326e0543801014ae70dadf2668ab8dc53ebb77423d292d485862afa54655cc29e0ea7dcb719b2a25681bced796f01d700fc5f63fc SHA512 e89b35a494cef356d30c8775aa0a58ca86d2e9d87b229a9c6eba3141fcbf3081d5a17ae7c367096e9e40e35db29c7a6eb52c04f90c2ffc2042a60663c1916d0a

www-misc/hldig/hldig-1.0.2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="HTTP/HTML indexing and searching system"
+HOMEPAGE="https://github.com/solbu/hldig"
+SRC_URI="http://github.com/solbu/${PN}/archive/v${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ppc ppc64 x86"
+IUSE="libressl ssl"
+
+DEPEND="
+	!www-misc/htdig
+	sys-libs/zlib
+	app-arch/unzip
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-${PV}"
+
+HTML_DOCS=( docs/. )
+
+src_prepare() {
+	default
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac db/configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--with-config-dir="${EPREFIX}"/etc/${PN}
+		--with-default-config-file="${EPREFIX}"/etc/${PN}/${PN}.conf
+		--with-database-dir="${EPREFIX}"/var/lib/${PN}/db
+		--with-cgi-bin-dir="${EPREFIX}"/var/www/localhost/cgi-bin
+		--with-search-dir="${EPREFIX}"/var/www/localhost/hldocs/${PN}
+		--with-image-dir="${EPREFIX}"/var/www/localhost/hldocs/${PN}
+		$(use_with ssl)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install () {
+	default
+	sed -i "s:${D}::g" \
+		"${ED}"/etc/${PN}/${PN}.conf \
+		"${ED}"/usr/bin/rundig \
+		|| die "sed failed (removing \${D} from installed files)"
+
+	keepdir "${EPREFIX}"/var/lib/${PN}/db
+
+	# Symlink hlsearch so it can be easily found.
+	dosym ../../var/www/localhost/cgi-bin/hlsearch /usr/bin/hlsearch
+
+	# No static archives
+	find "${D}" -name '*.la' -delete || die
+}

www-misc/hldig/metadata.xml

@@ -0,0 +1,7 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Chris</name>
+	</maintainer>
+</pkgmetadata>