#################################################
#
#  (C) 2010-2011 Serghei Amelian
#  serghei (DOT) amelian (AT) gmail.com
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################

include_directories(
  ${CMAKE_CURRENT_BINARY_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}/../../interfaces
  ${CMAKE_BINARY_DIR}
  ${CMAKE_BINARY_DIR}/kmail
  ${CMAKE_SOURCE_DIR}
  ${CMAKE_SOURCE_DIR}/libkdepim
  ${CMAKE_SOURCE_DIR}/kmail
  ${CMAKE_SOURCE_DIR}/certmanager/lib
  ${CMAKE_SOURCE_DIR}/libkdenetwork
  ${TDE_INCLUDE_DIR}
  ${TQT_INCLUDE_DIRS}
  ${GPGME_INCLUDE_DIRS}
)

link_directories(
  ${TQT_LIBRARY_DIRS}
)


##### other data ################################

install( FILES kcmkmailsummary.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
install( FILES kmailplugin.desktop DESTINATION ${SERVICES_INSTALL_DIR}/kontact )


##### helper ####################################

macro( process_kcfg _who _out _path _kcfg _kcfgc )
  add_custom_command( OUTPUT ${CMAKE_BINARY_DIR}/${_path}/${_out}
    COMMAND
      mkdir -p ${CMAKE_BINARY_DIR}/${_path}
    COMMAND ${KDE3_KCFGC_EXECUTABLE}
      -d ${CMAKE_BINARY_DIR}/${_path}
      ${CMAKE_SOURCE_DIR}/${_path}/${_kcfg}
      ${CMAKE_SOURCE_DIR}/${_path}/${_kcfgc}
    DEPENDS
      ${CMAKE_SOURCE_DIR}/${_path}/${_kcfg}
      ${CMAKE_SOURCE_DIR}/${_path}/${_kcfgc} )
  set_property( SOURCE ${_who} APPEND
    PROPERTY OBJECT_DEPENDS ${CMAKE_BINARY_DIR}/${_path}/${_out} )
endmacro()


##### libkontact_kmailplugin (module) ###########

set( KDE3_DCOPIDL_EXECUTABLE ${KDE3_DCOPIDLNG_EXECUTABLE} )

process_kcfg( kmail_plugin.cpp globalsettings_base.h kmail
    kmail.kcfg globalsettings_base.kcfgc )

add_custom_command( OUTPUT ${CMAKE_BINARY_DIR}/kmail/templatesconfiguration_base.h
    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/kmail
    COMMAND ${CMAKE_COMMAND}
      -DQT_UIC_EXECUTABLE:FILEPATH=${QT_UIC_EXECUTABLE}
      -DTDE_QTPLUGINS_DIR:FILEPATH=${TDE_QTPLUGINS_DIR}
      -DUI_FILE:FILEPATH=${CMAKE_SOURCE_DIR}/kmail/templatesconfiguration_base.ui
      -P ${CMAKE_MODULE_PATH}/tde_uic.cmake
    DEPENDS
      ${CMAKE_BINARY_DIR}/kmail/globalsettings_base.h
      ${CMAKE_SOURCE_DIR}/kmail/templatesconfiguration_base.ui )

set_property( SOURCE kmail_plugin.cpp APPEND
  PROPERTY OBJECT_DEPENDS ${CMAKE_BINARY_DIR}/kmail/templatesconfiguration_base.h )

tde_add_kpart( libkontact_kmailplugin AUTOMOC
  SOURCES
    kmail_plugin.cpp summarywidget.cpp summarywidget.skel
    ${CMAKE_SOURCE_DIR}/kmail/kmailIface.stub
  LINK kpinterfaces-shared
  DESTINATION ${PLUGIN_INSTALL_DIR}
)


##### kcm_kmailsummary (module) #################

tde_add_kpart( kcm_kmailsummary AUTOMOC
  SOURCES kcmkmailsummary.cpp
  LINK kdeui-shared
  DESTINATION ${PLUGIN_INSTALL_DIR}
)
