#1 cmake conversion

Merged
SlavekB merged 3 commits from feat/cmakeConv into master 1 year ago
  1. +78
    -0
      CMakeLists.txt
  2. +45
    -0
      ConfigureChecks.cmake
  3. +8
    -0
      config.h.cmake
  4. +1
    -0
      doc/CMakeLists.txt
  5. +0
    -0
      doc/Makefile.am
  6. +4
    -0
      doc/cs/CMakeLists.txt
  7. +0
    -0
      doc/cs/Makefile.am
  8. +1
    -0
      doc/en/CMakeLists.txt
  9. +0
    -0
      doc/en/Makefile.am
  10. +5
    -0
      doc/man/CMakeLists.txt
  11. +42
    -0
      doc/man/knutclient.1
  12. +6
    -0
      pics/CMakeLists.txt
  13. +1
    -0
      po/CMakeLists.txt
  14. +61
    -0
      src/CMakeLists.txt

+ 78
- 0
CMakeLists.txt View File

@@ -0,0 +1,78 @@
############################################
# #
# Improvements and feedbacks are welcome #
# #
# This file is released under GPL >= 3 #
# #
############################################


cmake_minimum_required( VERSION 2.8 )


#### general package setup

project( knutclient )
set( VERSION R14.1.0 )


#### include essential cmake modules

include( FindPkgConfig )
include( CheckFunctionExists )
include( CheckIncludeFile )
include( CheckLibraryExists )
include( CheckCSourceCompiles )
include( CheckCXXSourceCompiles )


#### include our cmake modules

set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
include( TDEMacros )


##### setup install paths

include( TDESetupPaths )
tde_setup_paths( )


##### optional stuff

option( WITH_ALL_OPTIONS "Enable all optional support" OFF )
option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )


##### user requested modules

option( BUILD_ALL "Build all" ON )
option( BUILD_DOC "Build documentation" ${BUILD_ALL} )
option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )


##### configure checks

include( ConfigureChecks.cmake )


###### global compiler settings

add_definitions( -DHAVE_CONFIG_H -UTQT_NO_ASCII_CAST )

set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
set( CMAKE_SHARED_LINKER_FLAGS "-Wl,--no-undefined" )
set( CMAKE_MODULE_LINKER_FLAGS "-Wl,--no-undefined" )


##### directories

add_subdirectory( src )
add_subdirectory( pics )
tde_conditional_add_subdirectory( BUILD_DOC doc )
tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po )


##### write configure files

configure_file( config.h.cmake config.h @ONLY )

+ 45
- 0
ConfigureChecks.cmake View File

@@ -0,0 +1,45 @@
###########################################
# #
# Improvements and feedback are welcome #
# #
# This file is released under GPL >= 3 #
# #
###########################################


# required stuff
find_package( TQt )
find_package( TDE )

tde_setup_architecture_flags( )

include(TestBigEndian)
test_big_endian(WORDS_BIGENDIAN)


##### check for gcc visibility support

if( WITH_GCC_VISIBILITY )
if( NOT UNIX )
tde_message_fatal( "gcc visibility support was requested, but your system is not *NIX" )
endif( NOT UNIX )
set( __KDE_HAVE_GCC_VISIBILITY 1 )
set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
endif( WITH_GCC_VISIBILITY )


##### gettext

if( BUILD_TRANSLATIONS )
include( FindGettext )
if( GETTEXT_FOUND )
set( MSGFMT_EXECUTABLE ${GETTEXT_MSGFMT_EXECUTABLE}
CACHE FILEPATH "path to msgfmt executable" )
endif( GETTEXT_FOUND )
if( NOT MSGFMT_EXECUTABLE )
tde_message_fatal( "msgfmt is required but was not found on your system." )
endif( NOT MSGFMT_EXECUTABLE )
endif( BUILD_TRANSLATIONS )


+ 8
- 0
config.h.cmake View File

@@ -0,0 +1,8 @@
#define VERSION "@VERSION@"

// Defined if you have fvisibility and fvisibility-inlines-hidden support.
#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1

/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
significant byte first (like Motorola and SPARC, unlike Intel). */
#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@

+ 1
- 0
doc/CMakeLists.txt View File

@@ -0,0 +1 @@
tde_auto_add_subdirectories( )

+ 0
- 0
doc/Makefile.am View File


+ 4
- 0
doc/cs/CMakeLists.txt View File

@@ -0,0 +1,4 @@
tde_create_handbook(
DESTINATION ${PROJECT_NAME}
LANG cs
)

+ 0
- 0
doc/cs/Makefile.am View File


+ 1
- 0
doc/en/CMakeLists.txt View File

@@ -0,0 +1 @@
tde_create_handbook( DESTINATION ${PROJECT_NAME} )

+ 0
- 0
doc/en/Makefile.am View File


+ 5
- 0
doc/man/CMakeLists.txt View File

@@ -0,0 +1,5 @@
INSTALL(
FILES ${PROJECT_NAME}.1
DESTINATION ${MAN_INSTALL_DIR}/man1
COMPONENT doc
)

+ 42
- 0
doc/man/knutclient.1 View File

@@ -0,0 +1,42 @@
.TH KNUTCLIENT 1 "july 8, 2004"
.SH NAME
knutclient \- A TDE GUI that displays UPS statistics from NUT's upsd
.SH SYNOPSIS
.B knutclient [option]
.br
.SH DESCRIPTION
This manual page documents briefly the
.B knutclient
program.
This manual page was written for the Debian distribution
because the original program does not have a manual page.
Instead, it has documentation in the TDE Help format you
should better refer to.
.PP
\fBknutclient\fP monitors UPS statistics through the NUT (Network UPS Tools,
http://www.networkupstools.org/) framework on Linux and other systems. This
information, presented in a nice visual format, can be invaluable on stations
using an UPS.

.SH OPTIONS
This program follow the usual GNU command line syntax, with long
options starting with two dashes (`-').
A summary of options is included below.
For a complete description, see the TDE Help.
.TP
.B \-\-help
Show summary of options.
.TP
.B \-v, \-\-version
Show version of program.
.TP
.B \-v, \-\-author
Show author of program.
.SH SEE ALSO
.BR upsc (8),
.BR upsd (8).
.br
The NUT (Network UPS Tools) home page: http://www.networkupstools.org/
.SH AUTHOR
This manual page was written by Arnaud Quette <arnaud.quette@free.fr>,
for the Debian project (but may be used by others).

+ 6
- 0
pics/CMakeLists.txt View File

@@ -0,0 +1,6 @@
file( GLOB _pics RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.png )

install(
FILES ${_pics}
DESTINATION ${DATA_INSTALL_DIR}/${PROJECT_NAME}/pics
)

+ 1
- 0
po/CMakeLists.txt View File

@@ -0,0 +1 @@
tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )

+ 61
- 0
src/CMakeLists.txt View File

@@ -0,0 +1,61 @@
include_directories(
${CMAKE_BINARY_DIR}
${CMAKE_CURRENT_BINARY_DIR}
${CMAKE_CURRENT_SOURCE_DIR}
${TDE_INCLUDE_DIR}
${TQT_INCLUDE_DIRS}
)

link_directories(
${TQT_LIBRARY_DIRS}
${TDE_LIB_DIR}
)


##### knutclient (executable)

tde_add_executable( ${PROJECT_NAME} AUTOMOC

SOURCES
main.cpp
knutclient.cpp
knutmainwindow.cpp
knutprefdlg.cpp
knutnewupsdlg.cpp
knutupsdata.cpp
knutvardata.cpp
knutnet.cpp
knutfrontpanel.cpp
knutpanelmeter.cpp
knutdock.cpp
knutprintupsvar.cpp
knutinstcomms.cpp
knutrwvar.cpp
knutanalog.cpp
knutmessagemanager.cpp
knutmessage.cpp
LINK
tdecore-shared
tdeui-shared
tdeio-shared
DESTINATION ${BIN_INSTALL_DIR}
)


##### icons

tde_install_icons( )


##### other data

install(
FILES knutclientui.rc
DESTINATION ${DATA_INSTALL_DIR}/${PROJECT_NAME}
)

install(
FILES ${PROJECT_NAME}.desktop
DESTINATION ${APPS_INSTALL_DIR}/Utilities
)

Loading…
Cancel
Save